//e[Single]
#ScriptVersion[3]
#ID["DT_31_SAKUYA_N01"]
//System["script/default_system/Default_System.txt"]
#Title["SAKUYA_N01"]
#Text[""]
//Image[""]
//Background["script/default_system/Default_Background_IceMountain.txt"]
//Player[]

#include "./../../cmn/common.txt"
#include "./../../cmn/shotConst.txt"
#include "./../../cmn/Effect.txt"
#include "./../../cmn/boss/commonBossFunc.txt"
#include "./../../cmn/commonFunc.txt"
#include "./../../cmn/lib/lib_anime_Sakuya.txt"

let objEnemy;	//GIuWFNg
let pathDot = GetCurrentScriptDirectory() ~ "./../../img/sakuya_dot.png";
//let pathCutin = GetCurrentScriptDirectory() ~ "./../../img/sakuya_cutin.png";
let pathTimer = GetCurrentScriptDirectory() ~ "./../../se/timer.wav";
let pathShot = GetCurrentScriptDirectory() ~ "./../../se/shot0.wav";

@Loading{
	if(!IsCommonDataAreaExists(nsStage)){
		LoadTexture(pathDot);
//		LoadTexture(pathCutin);
		LoadSound(pathTimer);
		LoadSound(pathShot);
	}
}

@Initialize{
	objEnemy = ObjEnemy_Create(OBJ_ENEMY_BOSS);
	ObjEnemy_Regist(objEnemy);
	
	ObjEnemy_SetDamageRate(objEnemy, 0, 0);
	SetShotAutoDeleteClip(64,64,64,64);
	
	InitializeAction(objEnemy, pathDot);
	Render();
//	BackGround(pathCutin, 450, 600);
	Schedule();
}

@MainLoop{
	let ex = ObjMove_GetX(objEnemy);
	let ey = ObjMove_GetY(objEnemy);
	ObjEnemy_SetIntersectionCircleToShot(objEnemy, ex, ey, 32);//蔻(e)o^
	ObjEnemy_SetIntersectionCircleToPlayer(objEnemy, ex, ey, 24);//蔻(̓)o^
	
	yield;
}

@Event{
	alternative(GetEventType())
	case(EV_REQUEST_LIFE){
		SetScriptResult(2500);	//Ctݒ
	}
	case(EV_REQUEST_TIMER){
		let timerBoss = 60;
		SetScriptResult(timerBoss);	//Ԑݒ
		TimerSE(timerBoss);
	}
	case(EV_REQUEST_SPELL_SCORE){
//		SetScriptResult(10);	//XyJ[h{[iXݒ
//		T_SpellCardBonus(50000);
	}
//	case(EV_REQUEST_IS_DURABLE_SPELL){
//		SetScriptResult(true);	//ϋvXyJݒ
//	}
	others{}
}

@Finalize{}

task Schedule(){
//	ObjMove_SetX(objEnemy, GetStgFrameWidth()+64);
//	ObjMove_SetY(objEnemy, GetStgFrameHeight()/2);
	ObjMove_SetDestAtFrame(objEnemy, GetStgFrameWidth()-100, GetStgFrameHeight()/2, 60);
	SetAction(ACT_MOVE, 60);
	Wait(60);
	
//	ObjEnemyBossScene_StartSpell(GetEnemyBossSceneObjectID());
//	CutIn(pathCutin,180,191,450,600);
//	SetAction(ACT_SPELL,120);
//	Wait(180);
	
	Fire();
	End(-1);
	
	Wait(30);
	SetDamageRateType();
}

//U
task Fire(){
	let way = 11;
	let angA = rand(0,360);
	let angB = rand(0,360);
	
	Move();
	
	loop{
		loop(way){
			Knife(angA,S_KNIFE+S_RED);
			angA += (360/way);
		}
		angA += 7;
		angA %= 360;
		Wait(6);
		if(ObjEnemy_GetInfo(objEnemy, INFO_LIFE) <= 0){	return;	}
		loop(way){
			Knife(angB,S_KNIFE+S_BLUE);
			angB += (360/way);
		}
		angB -= 7;
		angB %= 360;
		Wait(6);
		if(ObjEnemy_GetInfo(objEnemy, INFO_LIFE) <= 0){	return;	}
	}
}

function Knife(let ang,let clr){
	let shot;
	shot = CreateShotA1(ObjMove_GetX(objEnemy),ObjMove_GetY(objEnemy),3,ang,clr,0);
	Shot_Modify(shot);
	shot = CreateShotA1(ObjMove_GetX(objEnemy)+8*cos(ang+90),ObjMove_GetY(objEnemy)+8*sin(ang+90),3,ang,clr,0);
	Shot_Modify(shot);
	shot = CreateShotA1(ObjMove_GetX(objEnemy)+8*cos(ang-90),ObjMove_GetY(objEnemy)+8*sin(ang-90),3,ang,clr,0);
	Shot_Modify(shot);
}

task Move(){
	let way = 10;
	let ang = 0;
	let shot;
	
	loop{
		PlaySE(pathShot);
		ang = GetAngleToPlayer(objEnemy);
		loop(10){
			loop(way){
				shot = CreateShotA1(ObjMove_GetX(objEnemy),ObjMove_GetY(objEnemy),3.5,ang,S_KNIFE+S_RPURPLE,0);
				Shot_Modify(shot);
				ang += (360/way);
			}
			Wait(5);
			if(ObjEnemy_GetInfo(objEnemy, INFO_LIFE) <= 0){	return;	}
		}
		Wait(10);
		SetAction(ACT_MOVE,60);
		SetMoveBoss(60);
		Wait(60);
	}
}
