//e[Single]
#ScriptVersion[3]
#ID["DT_31_ALICE_S02"]
//System["script/default_system/Default_System.txt"]
#Title["ALICE_S02"]
#Text[""]
//Image[""]
//Background["script/default_system/Default_Background_IceMountain.txt"]
//Player[]

#include "./../../cmn/common.txt"
#include "./../../cmn/shotConst.txt"
#include "./../../cmn/Effect.txt"
#include "./../../cmn/boss/commonBossFunc.txt"
#include "./../../cmn/commonFunc.txt"
#include "./../../cmn/lib/lib_anime_Alice.txt"

let objEnemy;	//GIuWFNg
let pathDot = GetCurrentScriptDirectory() ~ "./../../img/alice_dot.png";
let pathCutin = GetCurrentScriptDirectory() ~ "./../../img/alice_cutin.png";
let pathTimer = GetCurrentScriptDirectory() ~ "./../../se/timer.wav";
let pathShot = GetCurrentScriptDirectory() ~ "./../../se/shot0.wav";

@Loading{
	if(!IsCommonDataAreaExists(nsStage)){
		LoadTexture(pathDot);
		LoadTexture(pathCutin);
		LoadSound(pathTimer);
		LoadSound(pathShot);
	}
}

@Initialize{
	objEnemy = ObjEnemy_Create(OBJ_ENEMY_BOSS);
	ObjEnemy_Regist(objEnemy);
	
	ObjEnemy_SetDamageRate(objEnemy, 0, 0);
	SetShotAutoDeleteClip(64,64,64,64);
	
	InitializeAction(objEnemy, pathDot);
	Render();
//	BackGround(pathCutin, 450, 600);
	Schedule();
}

@MainLoop{
	let ex = ObjMove_GetX(objEnemy);
	let ey = ObjMove_GetY(objEnemy);
	ObjEnemy_SetIntersectionCircleToShot(objEnemy, ex, ey, 32);//蔻(e)o^
	ObjEnemy_SetIntersectionCircleToPlayer(objEnemy, ex, ey, 24);//蔻(̓)o^
	
	yield;
}

@Event{
	alternative(GetEventType())
	case(EV_REQUEST_LIFE){
//		SetScriptResult(2500);	//Ctݒ
		SetScriptResult(1500);	//Ctݒ
	}
	case(EV_REQUEST_TIMER){
		let timerBoss = 60;
		SetScriptResult(timerBoss);	//Ԑݒ
		TimerSE(timerBoss);
	}
	case(EV_REQUEST_SPELL_SCORE){
		SetScriptResult(10);	//XyJ[h{[iXݒ
		T_SpellCardBonus(50000);
	}
//	case(EV_REQUEST_IS_DURABLE_SPELL){
//		SetScriptResult(true);	//ϋvXyJݒ
//	}
	others{}
}

@Finalize{}

task Schedule(){
//	ObjMove_SetX(objEnemy, GetStgFrameWidth()+64);
//	ObjMove_SetY(objEnemy, GetStgFrameHeight()/2);
	ObjMove_SetDestAtFrame(objEnemy, GetStgFrameWidth()-100, GetStgFrameHeight()/2, 60);
	SetAction(ACT_MOVE, 60);
	Wait(60);
	
	ObjEnemyBossScene_StartSpell(GetEnemyBossSceneObjectID());
	CutIn(pathCutin,180,191,450,600);
	SetAction(ACT_SPELL,120);
	Wait(180);
	
	Fire();
	End(-1);
	
	Wait(30);
	SetDamageRateType();
}

task Fire(){
	let ang;
	
	loop{
		SetAction(ACT_SHOT_A,36);
		Wait(12);
		PlaySE(pathShot);
		if(ObjEnemy_GetInfo(objEnemy, INFO_LIFE) <= 0){	return;	}
		ang = GetAngleToPlayer(objEnemy);
		BulletMaster(ang);
		Wait(24);
		SetAction(ACT_MOVE,45);
		SetMoveBoss(45);
		Wait(45);
	}
}

task BulletMaster(let ang){
	let shot = CreateShotA1(ObjMove_GetX(objEnemy),ObjMove_GetY(objEnemy),5,ang,S_HUGE+S_SP,0);
	Shot_Modify(shot);
	shot = CreateShotA1(ObjMove_GetX(objEnemy),ObjMove_GetY(objEnemy),5,ang,S_DOLL+S_BLUE,0);
	Shot_Modify(shot);
	ObjShot_SetSpellResist(shot,true);
	
	let tX = GetPlayerX();
	let tY = GetPlayerY();
	let len = 100;
	while(!Obj_IsDeleted(shot)){
		len = GetLengthToObj(ObjMove_GetX(shot),ObjMove_GetY(shot),tX,tY);
		if(len < 24){
			ObjMove_SetSpeed(shot,0);
			break;
		}
		yield;
	}
	
	Wait(30);
	if(Obj_IsDeleted(shot)){	return;	}
	if(ObjEnemy_GetInfo(objEnemy, INFO_LIFE) <= 0){	return;	}
	
	let bAng = 0;
	let id;
	let way = 8;
	loop(18){
		bAng = GetAngleToPlayer(shot);
		loop(way){
			id = CreateLooseLaserA1(ObjMove_GetX(shot),ObjMove_GetY(shot),4,bAng,50,10,S_SCALE_S+S_BLUE,0);
			Shot_Modify(id);
			bAng += (360/way);
		}
		Wait(10);
	}
	ObjShot_FadeDelete(shot);
}
