//e[Single]
#ScriptVersion[3]
#ID["DT_31_SAKUYA_S01"]
//System["script/default_system/Default_System.txt"]
#Title["SAKUYA_S01"]
#Text[""]
//Image[""]
//Background["script/default_system/Default_Background_IceMountain.txt"]
//Player[]

#include "./../../cmn/common.txt"
#include "./../../cmn/shotConst.txt"
#include "./../../cmn/Effect.txt"
#include "./../../cmn/boss/commonBossFunc.txt"
#include "./../../cmn/commonFunc.txt"
#include "./../../cmn/lib/lib_anime_Sakuya.txt"

let objEnemy;	//GIuWFNg
let pathDot = GetCurrentScriptDirectory() ~ "./../../img/sakuya_dot.png";
let pathCutin = GetCurrentScriptDirectory() ~ "./../../img/sakuya_cutin.png";
let pathTimer = GetCurrentScriptDirectory() ~ "./../../se/timer.wav";
let pathShot = GetCurrentScriptDirectory() ~ "./../../se/fire1.wav";

@Loading{
	if(!IsCommonDataAreaExists(nsStage)){
		LoadTexture(pathDot);
		LoadTexture(pathCutin);
		LoadSound(pathTimer);
		LoadSound(pathShot);
	}
}

@Initialize{
	objEnemy = ObjEnemy_Create(OBJ_ENEMY_BOSS);
	ObjEnemy_Regist(objEnemy);
	
	ObjEnemy_SetDamageRate(objEnemy, 0, 0);
	SetShotAutoDeleteClip(64,64,64,64);
	
	InitializeAction(objEnemy, pathDot);
	Render();
//	BackGround(pathCutin, 450, 600);
	Schedule();
}

@MainLoop{
	let ex = ObjMove_GetX(objEnemy);
	let ey = ObjMove_GetY(objEnemy);
	ObjEnemy_SetIntersectionCircleToShot(objEnemy, ex, ey, 32);//蔻(e)o^
	ObjEnemy_SetIntersectionCircleToPlayer(objEnemy, ex, ey, 24);//蔻(̓)o^
	
	yield;
}

@Event{
	alternative(GetEventType())
	case(EV_REQUEST_LIFE){
//		SetScriptResult(2500);	//Ctݒ
		SetScriptResult(2000);	//Ctݒ
	}
	case(EV_REQUEST_TIMER){
		let timerBoss = 60;
		SetScriptResult(timerBoss);	//Ԑݒ
		TimerSE(timerBoss);
	}
	case(EV_REQUEST_SPELL_SCORE){
		SetScriptResult(10);	//XyJ[h{[iXݒ
		T_SpellCardBonus(50000);
	}
//	case(EV_REQUEST_IS_DURABLE_SPELL){
//		SetScriptResult(true);	//ϋvXyJݒ
//	}
	others{}
}

@Finalize{}

task Schedule(){
//	ObjMove_SetX(objEnemy, GetStgFrameWidth()+64);
//	ObjMove_SetY(objEnemy, GetStgFrameHeight()/2);
	ObjMove_SetDestAtFrame(objEnemy, GetStgFrameWidth()-100, GetStgFrameHeight()/2, 60);
	SetAction(ACT_MOVE, 60);
	Wait(60);
	
	ObjEnemyBossScene_StartSpell(GetEnemyBossSceneObjectID());
	CutIn(pathCutin,180,191,450,600);
	SetAction(ACT_SPELL,120);
	Wait(180);
	
	Fire();
	End(-1);
	
	Wait(30);
	SetDamageRateType();
}

//U
task Fire(){
	let way = 9;
	let ang = 0;
	
	loop{
		SetAction(ACT_SHOT_A,36);
		Wait(12);
		if(ObjEnemy_GetInfo(objEnemy, INFO_LIFE) <= 0){	return;	}
		ang = rand(0,360);
		PlaySE(pathShot);
		loop(way){
			BulletKnife(ang);
			ang += (360/way);
		}
		Wait(24);
		SetAction(ACT_MOVE,45);
		SetMoveBoss(45);
		Wait(45);
	}
}

task BulletKnife(let ang){
	let shot = CreateShotA1(ObjMove_GetX(objEnemy),ObjMove_GetY(objEnemy),4,ang,S_NORMAL+S_RED,0);
	BulletEffect(shot);
	ObjShot_SetSpellResist(shot,true);
	Shot_Modify(shot);
	
	loop{
		if(ObjMove_GetX(shot) > GetStgFrameWidth() || ObjMove_GetX(shot) < 0){
			Bullet(ObjMove_GetX(shot),ObjMove_GetY(shot));
			break;
		}else if(ObjMove_GetY(shot) > GetStgFrameHeight() || ObjMove_GetY(shot) < 0){
			Bullet(ObjMove_GetX(shot),ObjMove_GetY(shot));
			break;
		}
		yield;
	}
	EraseEffect(ObjMove_GetX(shot),ObjMove_GetY(shot),255,32,32,30,2);
	Obj_Delete(shot);
}

task BulletEffect(let id){
	let dmy = CreateShotA1(ObjMove_GetX(id),ObjMove_GetY(id),0,0,S_NORMAL+S_RED,10);
	ObjShot_SetSpellResist(dmy,true);
	Shot_Modify(dmy);
	while(!Obj_IsDeleted(id)){
		ObjShot_SetDelay(dmy,24);
		ObjMove_SetX(dmy,ObjMove_GetX(id));
		ObjMove_SetY(dmy,ObjMove_GetY(id));
		yield;
	}
	Obj_Delete(dmy);
}

task Bullet(let x,let y){
	let num = 10;
	let ang = GetAngleToObj(x,y,GetPlayerX(),GetPlayerY());
	let shot;
	
	loop(num){
		shot = CreateShotA1(x,y,4,ang,S_KNIFE+S_ORANGE,0);
		Shot_Modify(shot);
		Wait(5);
	}
}
