#東方弾幕風
#Title[想起「ムーンサイムムーンンンサササイイド」]
#Text[試作]
#ScriptVersion[2]

script_enemy_main
{
	let scroll=0;
	let flag=0;
	let cx=GetCenterX();
	let cy=GetCenterY();
	let boss=GetCurrentScriptDirectory~"img\boss7-3.png";
	let eye=GetCurrentScriptDirectory~"img\bg7-1.5.png";
	let asa=GetCurrentScriptDirectory~"img\bg7-2.5.png";
	LoadUserShotData(GetCurrentScriptDirectory~"shot.txt");
	@Initialize
	{
		SetScore(30000);
		SetLife(500);
		SetDamageRate(10,0);
		SetMovePosition02(cx,cy-120,60);
		SetTimer(80);
		SetInvincibility(60);
		LoadGraphic(boss);
		LoadGraphic(eye);
		LoadGraphic(asa);
		LoadGraphic(GetCurrentScriptDirectory~".\img\shot\bullet.png");
		shottask;
		shottask2;
		drawtask;
		bombtask;
		CutIn(YOUMU,"想起「ムーンサイムムーンンンサササイイド」",0,0,0,0,0);
	}
	@MainLoop
	{
		yield;
	}
	@Finalize
	{
		loop(16)
		{
			CreateItem(ITEM_SCORE,GetX+rand(-30,30),GetY+rand(-30,30));
		}
		DeleteGraphic(boss);
		DeleteGraphic(eye);
		DeleteGraphic(asa);
		DeleteGraphic(GetCurrentScriptDirectory~".\img\shot\bullet.png");
	}
	@DrawLoop
	{
		SetTexture(boss);	
		if(flag==1)
		{
			SetGraphicRect(52,0,81,63);
		}
		else if(flag==2)
		{
			SetGraphicRect(24,0,52,63);
		}
		else
		{
			SetGraphicRect(0,0,24,63);
		}
		SetGraphicScale(1,1);
		SetGraphicAngle(0,0,0);
		DrawGraphic(GetX,GetY);
	}
	@BackGround
	{
		SetTexture(eye);	
		SetGraphicRect(0,0,384,448);
		SetAlpha(255);
		SetGraphicScale(1,1);
		SetGraphicAngle(0,0,0);
		DrawGraphic(cx,cy);
		SetTexture(asa);	
		SetGraphicRect(0,0,888,189*5);
		SetAlpha(255);
		SetGraphicScale(0.5,0.75);
		SetGraphicAngle(0,0,0);
		DrawGraphic(cx+scroll,cy);
		DrawGraphic(cx+scroll-444,cy);
		if(scroll>444)
		{
			scroll=0;
		}
	}
	task shottask
	{
		let angle=0;
		let angle2=0;
		wait(120);
		loop
		{
			SetShotColor(255,0,0);
			CreateObjLaser(GetX,GetY,angle2+120,512,16,254,3,90);
			SetShotColor(0,255,0);
			CreateObjLaser(GetX,GetY,angle2+240,512,16,254,3,90);
			SetShotColor(0,0,255);
			CreateObjLaser(GetX,GetY,angle2,512,16,254,3,90);
			SetShotColor(255,255,255);
			angle2+=23;
			wait(3);
		}
	}
	task shottask2
	{
		wait(270);
		loop
		{
			SetShotColor(255,0,0);
			CreateShot01(GetX+3*cos(GetAngleToPlayer),GetY+3*sin(GetAngleToPlayer),1.5,GetAngleToPlayer,157,0);
			SetShotColor(0,255,0);
			CreateShot01(GetX+3*cos(GetAngleToPlayer+120),GetY+3*sin(GetAngleToPlayer+120),1.5,GetAngleToPlayer,157,0);
			SetShotColor(0,0,255);
			CreateShot01(GetX+3*cos(GetAngleToPlayer+240),GetY+3*sin(GetAngleToPlayer+240),1.5,GetAngleToPlayer,157,0);
			SetShotColor(255,255,255);
			wait(240);
		}
	}
	task drawtask
	{
		let x=0;
		loop
		{	
			if(GetX>x+0.5)
			{
				flag=1;
			}
			else if(GetX<x-0.5)
			{
				flag=2;
			}
			else
			{
				flag=0;
			}
			x=GetX;
			scroll++;
			yield;
		}
	}
	task bombtask
	{
		loop
		{
			if(OnBomb)
			{
				SetAlpha(64);
				SetDamageRate(0,0);
			}
			else
			{
				SetAlpha(255);
				SetDamageRate(10,0);
				SetCollisionA(GetX(),GetY(),24);
				SetCollisionB(GetX(),GetY(),24);
			}
			yield;
		}
	}
	task CreateObjLaser(let x, let y, let angle, let length,let width, let graphic, let angle2, let r)
	{
		let count=0;
		let obj = Obj_Create(OBJ_LASER);
		Obj_SetPosition(obj, x, y);
		Obj_SetSpeed(obj, 0);
		Obj_SetAngle(obj, angle);
		ObjShot_SetGraphic(obj, graphic);
		ObjShot_SetDelay(obj, 90);
		ObjLaser_SetLength(obj, length);
		ObjLaser_SetWidth(obj, width);
		Obj_SetAutoDelete(obj,false);ObjLaser_SetSource(obj,false);

		while(!Obj_BeDeleted(obj))
		{
			if(count==136)
			{
				Obj_Delete(obj);
				CreateShotA(1,Obj_GetX(obj),Obj_GetY(obj),0);
				SetShotDataA(1,0,3,angle+180,0,0,0,77);
				SetShotKillTime(1,30);
				FireShot(1);
			}
			if(count>=120)
			{
				width--;
				Obj_SetCollisionToPlayer(obj,false);
			}
			if(count<60)
			{
				angle+=angle2;
				ObjLaser_SetLength(obj, length*(count/60));
			}
			Obj_SetPosition(obj,GetX+r*cos(angle), GetY+r*sin(angle));
			Obj_SetAngle(obj, angle+30*angle2);
			ObjLaser_SetWidth(obj, width);
			count++;
			yield;
		}
	}
	function wait(w) 
	{
		loop(w)
		{
			yield;
		}
	}
}
