//注意
//このファイルは夢終劇仕様ドットアニメライブラリを改変したもので
//引用加工ドット絵に付属している物です。
//オリジナルの動作はこれを使用しないとエラーが出ます。
//通常版と同じように使用できます。 
//==============================================================================
//	★ボス共通 アニメライブラリ
//　ボス個別アニメライブラリ冒頭にてインクルードする
//==============================================================================
//　定数、変数
//==============================================================================
//　アクション定数
//　ボスドット絵の各カットの配置番号
//　	1  5  9 13 17 21   25 29
//　	2  6 10 14 18 22   26 30
//　	3  7 11 15 19 23   27 31
//　	4  8 12 16 20 24   28 32
//　各定数におけるアニメパターンは各コメントを参照（*は状況に応じて長く表示）
//------------------------------------------------------------------------------
let _ACT_STAND1		= -1;	//　立ち（アニメなし）		 1
let _ACT_STAND3		= 0;	//　立ち＋まばたき（3コマ）	 1-  2-  3-… 1-  5-  6-…
let _ACT_STAND4		= 1;	//　立ち＋まばたき（4コマ）	 1-  2-  3-  4-… 1-  5-  6-  4-…
let _ACT_STAND4_B	= 2;	//　立ち＋まばたき（4コマB） 1-  2-  3-  4-… 1-  5-  6-  4-…
let _ACT_MOVE		= 3;	//　移動（左右自動判定）	
let _ACT_MOVE_L		= 4;	//　左移動					 9-*10-  9
let _ACT_MOVE_R		= 5;	//　右移動					11-*12- 11
let _ACT_KICK		= 6;	//　キック移動（左右自動判定）	
let _ACT_KICK_L		= 7;	//　左キック移動			11-*12- 11
let _ACT_KICK_R		= 8;	//　右キック移動			 9-*10-  9
let _ACT_SHOT_A3	= 9;	//　弾幕A（3コマ）			17-*18- 17
let _ACT_SHOT_A3_B	= 10;	//　弾幕A（3コマB）			17- 18-*19
let _ACT_SHOT_A4	= 11;	//　弾幕A（4コマ）			17- 18-*19- 18
let _ACT_SHOT_A5	= 12;	//　弾幕A（5コマ）			17- 18-*19- 18- 17
let _ACT_SHOT_B3	= 13;	//　弾幕B（3コマ）			21-*22- 21
let _ACT_SHOT_B3_B 	= 14;	//　弾幕B（3コマB）			21- 23-*24
let _ACT_SHOT_B3_C	= 15;	//　弾幕B（3コマC）			23-*24- 23
let _ACT_SHOT_B4	= 16;	//　弾幕B（4コマ）			21- 22-*23- 22
let _ACT_SHOT_B5	= 17;	//　弾幕B（5コマ）			21- 22-*23- 22- 21
let _ACT_SHOT_B5_B	= 18;	//　弾幕B（5コマB）			21- 22-*24- 22- 21
let _ACT_SPELL3		= 19;	//　スペル発動（3コマ）		13-*14- 13
let _ACT_SPELL4		= 20;	//　スペル発動（4コマ）		13- 14-*15- 14
let _ACT_SPELL5		= 21;	//　スペル発動（5コマ）		13- 14-*15- 14- 13
let _ACT_SPELL5_B	= 22;	//　スペル発動（5コマB）	13- 14- 15-*16- 15
let _ACT_CHARGE		= 23;	//	溜め					21-*22
let _ACT_SLASH_H	= 24;	//　横斬り					21-*22- 20- 18- 17
let _ACT_SLASH_V	= 25;	//　縦斬り					23-*24- 20- 18- 17
let _ACT_TURN		= 26;	//　ターン					25- 29- 30- 31- 32- 25
let _ACT_PRAY		= 27;	//　祈祷					25-*(26- 27- 28- 29- 30- 31-…)- 32
let _ACT_SUN		= 28;	//　太陽					25-*(26- 27-…)-28
let _ACT_MOVE_Tenco	= 29;	//　天子専用移動（左右自動判定）	
let _ACT_MOVE_L_Tenco	= 30;	//　天子専用左移動					 9-*10-  9
let _ACT_MOVE_R_Tenco	= 31;	//　天子専用右移動					11-*12- 11
let _ACT_SPELL5_C	= 32;	//　天子専用スペル発動（5コマ）			14- 13- 14- 15-*16
let _ACT_SLASH_H_B	= 33;	//　天子専用横斬り（4コマ）			21-*22- 23- 24
let _ACT_SPELL4_B	= 34;	//　スペル発動（4コマB）			13- 14- 15-*16
let _ACT_THORN		= 35;	//　衣玖専用特殊動作			25- 26- 27-*(28- 29-…)- 30- 31- 32
let _ACT_SHOT_A4_B	= 36;	//　弾幕A（4コマB）			17- 18- 19-*20

//------------------------------------------------------------------------------
//　カット別矩形座標定数（左上の座標）
//　各定数が示すカットはコメント及びアクション定数のカット配置番号を参照
//------------------------------------------------------------------------------
let RECT_LENGTH		= 128;
let RECT_STAND0		= [ 0, 0 ];								//	 1
let RECT_STAND1		= [ 0, RECT_LENGTH ];					//	 2
let RECT_STAND2		= [ 0, 2 * RECT_LENGTH ];				//	 3
let RECT_STAND3		= [ 0, 3 * RECT_LENGTH ];				//	 4
let RECT_BLINK0		= [ RECT_LENGTH, 0 ];					//	 5
let RECT_BLINK1		= [ RECT_LENGTH, RECT_LENGTH ];			//	 6
let RECT_BLINK2		= [ RECT_LENGTH, 2 * RECT_LENGTH ];		//	 7
let RECT_MOVE_L0	= [ 2 * RECT_LENGTH, 0 ];				//	 9
let RECT_MOVE_L1	= [ 2 * RECT_LENGTH, RECT_LENGTH ];		//	10
let RECT_MOVE_R0	= [ 2 * RECT_LENGTH, 2 * RECT_LENGTH ];	//	11
let RECT_MOVE_R1	= [ 2 * RECT_LENGTH, 3 * RECT_LENGTH ];	//	12
let RECT_SPELL0		= [ 3 * RECT_LENGTH, 0 ];				//	13
let RECT_SPELL1		= [ 3 * RECT_LENGTH, RECT_LENGTH ];		//	14
let RECT_SPELL2		= [ 3 * RECT_LENGTH, 2 * RECT_LENGTH ];	//	15
let RECT_SPELL3		= [ 3 * RECT_LENGTH, 3 * RECT_LENGTH ];	//	16
let RECT_SHOT_A0	= [ 4 * RECT_LENGTH, 0 ];				//	17
let RECT_SHOT_A1	= [ 4 * RECT_LENGTH, RECT_LENGTH ];		//	18
let RECT_SHOT_A2	= [ 4 * RECT_LENGTH, 2 * RECT_LENGTH ];	//	19
let RECT_SHOT_A3	= [ 4 * RECT_LENGTH, 3 * RECT_LENGTH ];	//	20
let RECT_SHOT_B0	= [ 5 * RECT_LENGTH, 0 ];				//	21
let RECT_SHOT_B1	= [ 5 * RECT_LENGTH, RECT_LENGTH ];		//	22
let RECT_SHOT_B2	= [ 5 * RECT_LENGTH, 2 * RECT_LENGTH ];	//	23
let RECT_SHOT_B3	= [ 5 * RECT_LENGTH, 3 * RECT_LENGTH ];	//	24
let RECT_ETC_A0		= [ 6 * RECT_LENGTH, 0 ];				//	25
let RECT_ETC_A1		= [ 6 * RECT_LENGTH, RECT_LENGTH ];		//	26
let RECT_ETC_A2		= [ 6 * RECT_LENGTH, 2 * RECT_LENGTH ];	//	27
let RECT_ETC_A3		= [ 6 * RECT_LENGTH, 3 * RECT_LENGTH ];	//	28
let RECT_ETC_B0		= [ 7 * RECT_LENGTH, 0 ];				//	29
let RECT_ETC_B1		= [ 7 * RECT_LENGTH, RECT_LENGTH ];		//	30
let RECT_ETC_B2		= [ 7 * RECT_LENGTH, 2 * RECT_LENGTH ];	//	31
let RECT_ETC_B3		= [ 7 * RECT_LENGTH, 3 * RECT_LENGTH ];	//	32

//------------------------------------------------------------------------------
//　キャラ定数
//------------------------------------------------------------------------------
let CHAR_DAIYOUSEI	= 0;
let CHAR_MEIRIN		= 1;
let CHAR_DEVIL		= 2;
let CHAR_PATCHOULI	= 3;
let CHAR_SAKUYA		= 4;
let CHAR_REMILIA	= 5;
let CHAR_FLANDRE	= 6;
let CHAR_ALICE		= 7;
let CHAR_LILY		= 8;
let CHAR_YOUMU		= 9;
let CHAR_YUYUKO		= 10;
let CHAR_CHEN_RAN	= 11;
let CHAR_YUKARI		= 12;
let CHAR_TEWI		= 13;
let CHAR_REISEN		= 14;
let CHAR_EIRIN		= 15;
let CHAR_KAGUYA		= 16;
let CHAR_MOKOU		= 17;
let CHAR_SUIKA		= 18;
let CHAR_AYA		= 19;
let CHAR_MEDICINE	= 20;
let CHAR_YUKA		= 21;
let CHAR_KOMACHI	= 22;
let CHAR_EIKI		= 23;
let CHAR_SHINKI		= 24;
let CHAR_MIMA		= 25;
let CHAR_REIMU		= 26;
let CHAR_UTSUHO	        = 27;

//------------------------------------------------------------------------------
//　その他変数
//------------------------------------------------------------------------------
let actionDefault = _ACT_STAND1;	//　基本アクション
let action = actionDefault;			//　現在のアクション
let actionCount = 0;				//　アクションフレームカウンタ
let actionCountMax = 0;				//　アクション終了までのフレーム数
let stopAnime = false;				//　trueの間はアニメを停止する
let character = CHAR_DAIYOUSEI;		//　動作中のキャラクター

let BossShadowRect0=0;
let BossShadowRect1=0;

//==============================================================================
//　アクション指示関連関数
//==============================================================================
//　アクション初期設定
//------------------------------------------------------------------------------
task InitializeAction(){
	loop{
		SetAction( actionDefault, 0 );
		while( actionCount < actionCountMax ){
			while( stopAnime ){ waitaction(1); }
			actionCount ++;
			yield;
		}
	}
}

//------------------------------------------------------------------------------
//　アクション指定
//　※指定フレーム数が経過すると基本アクションに移行する
//　※「立ち」「幽香回転」はフレーム数固定（指定を無視する）
//------------------------------------------------------------------------------
function SetAction(
	let newAction,		//　アクション定数
	let frame			//　アクション終了までのフレーム数
){
	alternative( newAction )
	case( _ACT_STAND1, _ACT_STAND3, _ACT_STAND4, _ACT_STAND4_B ){ frame = 216000; }
	case( _ACT_TURN ){ frame = 42; }
	action = newAction;
	actionCount = 0;
	actionCountMax = frame;
}

//------------------------------------------------------------------------------
//　アニメ一時停止
//　※停止途中にすぐ再開したい場合は0以下のフレーム数を指定する
//------------------------------------------------------------------------------
task StopAnime(
	let frame		//　停止するフレーム数（経過後にアニメ再開）
){
	if( frame > 0 ){
		stopAnime = true;
		loop( frame ){
			if( !stopAnime ){ break; }
			yield;
		}
		stopAnime = false;
	}
	else{ stopAnime = false; }
}

//==============================================================================
//　描画関連関数
//==============================================================================
//　ボスアニメ描画（通常）
//------------------------------------------------------------------------------
function DrawBoss(
	let imageFile		//　画像ファイルパス
){
	_DrawBoss( imageFile, GetX(), GetY(),false,255,255,255);
}

function DrawBossAndShadow(
	let imageFile,	//　画像ファイルパス
	let R,
	let G,
	let B,
){
	_DrawBoss( imageFile, GetX(), GetY(), true ,R,G,B);
}

//------------------------------------------------------------------------------
//　ボスアニメ描画（座標指定）
//------------------------------------------------------------------------------
function _DrawBoss(
	let imageFile,		//　画像ファイルパス
	let x,				//	中心x座標
	let y,			//	中心y座標
	let ShadowAnimation,
	R,G,B
){
	let rect = [];
	alternative( action )
	//　3コマループ（立ち＋まばたき） --------------------------------
	case( _ACT_STAND3 ){
		let cutFrame = 12;
		let count = actionCount % ( cutFrame * 12 );
		let number = trunc( count / cutFrame );
		let anime = [ 0, 1, 2, 0, 1, 2, 0, 3, 4, 0, 1, 2, 2 ][ number ];
		rect = [ RECT_STAND0, RECT_STAND1, RECT_STAND2,
			RECT_BLINK0, RECT_BLINK1 ][ anime ];
	}
	//　4コマループ（立ち＋まばたき） --------------------------------
	case( _ACT_STAND4 ){
		let cutFrame = 12;
		let count = actionCount % ( cutFrame * 12 );
		let number = trunc( count / cutFrame );
		let anime = [ 0, 1, 2, 3, 0, 1, 2, 3, 0, 4, 5, 3, 3 ][ number ];
		rect = [ RECT_STAND0, RECT_STAND1, RECT_STAND2, RECT_STAND3,
			RECT_BLINK0, RECT_BLINK1 ][ anime ];
	}
	//　4コマループ（立ち＋まばたきB） -------------------------------
	case( _ACT_STAND4_B ){
		let cutFrame = 12;
		let count = actionCount % ( cutFrame * 12 );
		let number = trunc( count / cutFrame );
		let anime = [ 0, 1, 2, 3, 0, 1, 2, 3, 0, 4, 5, 6, 6 ][ number ];
		rect = [ RECT_STAND0, RECT_STAND1, RECT_STAND2, RECT_STAND3,
			RECT_BLINK0, RECT_BLINK1, RECT_BLINK2 ][ anime ];
	}
	//　3コマ移動（左右自動判定） ------------------------------------
	case( _ACT_MOVE, _ACT_KICK ,_ACT_MOVE_Tenco){
		if( absolute( GetSpeed() ) < 0.1 ){ rect = RECT_STAND0; }
		else{
			let cutFrameA = 10;
			if(action ==_ACT_MOVE_Tenco){cutFrameA = 7;}
			if( actionCountMax < 30 ){ cutFrameA = trunc( actionCountMax / 3 ); }
			let cutFrameB = actionCountMax - cutFrameA;
			let animePattern = [ 0, 1, 0 ];
			let framePattern = [ cutFrameA, cutFrameB, actionCountMax ];
			let anime = animePattern[ 2 ];
			ascent( let i in 0 .. 3 ){
				if( actionCount < framePattern[ i ] ){
					anime = animePattern[ i ];
					break;
				}
			}
			let moveL = cos( GetAngle() ) <= 0;
			if( action == _ACT_KICK ){ moveL = !moveL; }
			if( moveL ){ rect = [ RECT_MOVE_L0, RECT_MOVE_L1 ][ anime ]; }
			else{ rect = [ RECT_MOVE_R0, RECT_MOVE_R1 ][ anime ]; }
		}
	}

	//　3コマ移動（左右指定） ----------------------------------------
	case( _ACT_MOVE_L, _ACT_MOVE_R, _ACT_KICK_L, _ACT_KICK_R ,_ACT_MOVE_L_Tenco, _ACT_MOVE_R_Tenco){
		let cutFrameA = 10;
		if(action ==_ACT_MOVE_Tenco){cutFrameA = 7;}
		if( actionCountMax < 30 ){ cutFrameA = trunc( actionCountMax / 3 ); }
		let cutFrameB = actionCountMax - cutFrameA;
		let animePattern = [ 0, 1, 0 ];
		let framePattern = [ cutFrameA, cutFrameB, actionCountMax ];
		let anime = animePattern[ 2 ];
		ascent( let i in 0 .. 3 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		if( action == _ACT_MOVE_L || action == _ACT_KICK_R ){
			rect = [ RECT_MOVE_L0, RECT_MOVE_L1 ][ anime ];
		}
		else{ rect = [ RECT_MOVE_R0, RECT_MOVE_R1 ][ anime ]; }
	}

	//　3コマ（弾幕A3,B3,B3C,スペル3） -------------------------------
	case( _ACT_SHOT_A3, _ACT_SHOT_B3, _ACT_SHOT_B3_C, _ACT_SPELL3 ){
		let cutFrameA = 6;
		if( actionCountMax < 24 ){ cutFrameA = trunc( actionCountMax / 4 ); }
		let cutFrameB = actionCountMax - cutFrameA;
		let animePattern = [ 0, 1, 0 ];
		let framePattern = [ cutFrameA, cutFrameB, actionCountMax ];
		let anime = animePattern[ 2 ];
		ascent( let i in 0 .. 3 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		alternative( action )
		case( _ACT_SHOT_A3 ){ rect = [ RECT_SHOT_A0, RECT_SHOT_A1 ][ anime ]; }
		case( _ACT_SHOT_B3 ){ rect = [ RECT_SHOT_B0, RECT_SHOT_B1 ][ anime ]; }
		case( _ACT_SHOT_B3_C ){ rect = [ RECT_SHOT_B2, RECT_SHOT_B3 ][ anime ]; }
		others{ rect = [ RECT_SPELL0, RECT_SPELL1 ][ anime ]; }
	}
	//　3コマB（弾幕A3B,B3B） ----------------------------------------
	case( _ACT_SHOT_A3_B, _ACT_SHOT_B3_B ){
		let cutFrameA = 6;
		if( actionCountMax < 24 ){ cutFrameA = trunc( actionCountMax / 4 ); }
		let cutFrameB = cutFrameA * 2;
		let animePattern = [ 0, 1, 2 ];
		let framePattern = [ cutFrameA, cutFrameB, actionCountMax ];
		let anime = animePattern[ 2 ];
		ascent( let i in 0 .. 3 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		alternative( action )
		case( _ACT_SHOT_A3_B ){ rect = [ RECT_SHOT_A0, RECT_SHOT_A1, RECT_SHOT_A2 ][ anime ]; }
		others { rect = [ RECT_SHOT_B0, RECT_SHOT_B2, RECT_SHOT_B3 ][ anime ]; }
	}
	//　4コマ（弾幕A4,B4,スペル4） -----------------------------------
	case( _ACT_SHOT_A4, _ACT_SHOT_B4, _ACT_SPELL4 ){
		let cutFrameA = 6;
		if( actionCountMax < 30 ){ cutFrameA = trunc( actionCountMax / 5 ); }
		let cutFrameB = cutFrameA * 2;
		let cutFrameC = actionCountMax - cutFrameA;
		let animePattern = [ 0, 1, 2, 1 ];
		let framePattern = [ cutFrameA, cutFrameB, cutFrameC, actionCountMax ];
		let anime = animePattern[ 3 ];
		ascent( let i in 0 .. 4 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		alternative( action )
		case( _ACT_SHOT_A4 ){ rect = [ RECT_SHOT_A0, RECT_SHOT_A1, RECT_SHOT_A2 ][ anime ]; }
		case( _ACT_SHOT_B4 ){ rect = [ RECT_SHOT_B0, RECT_SHOT_B1, RECT_SHOT_B2 ][ anime ]; }
		others{ rect = [ RECT_SPELL0, RECT_SPELL1, RECT_SPELL2 ][ anime ]; }
	}
	//　4コマ（スペル4B,弾幕A4B） -----------------------------------
	case( _ACT_SPELL4_B, _ACT_SHOT_A4_B ){
		let cutFrameA = 6;
		if( actionCountMax < 30 ){ cutFrameA = trunc( actionCountMax / 5 ); }
		let cutFrameB = cutFrameA * 2;
		let cutFrameC = cutFrameA * 3;
		let cutFrameD = actionCountMax - cutFrameA;
		let animePattern = [ 0, 1, 2, 3 ];
		let framePattern = [ cutFrameA, cutFrameB, cutFrameC, cutFrameD ];
		let anime = animePattern[ 3 ];
		ascent( let i in 0 .. 4 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		alternative( action )
		case( _ACT_SPELL4_B ){ rect = [ RECT_SPELL0, RECT_SPELL1, RECT_SPELL2, RECT_SPELL3 ][ anime ]; }
		case( _ACT_SHOT_A4_B ){ rect = [RECT_SHOT_A0, RECT_SHOT_A1, RECT_SHOT_A2, RECT_SHOT_A3 ][ anime ]; }
	}
	//　5コマ（弾幕A5,B5,B5B,スペル5） -------------------------------
	case( _ACT_SHOT_A5, _ACT_SHOT_B5, _ACT_SHOT_B5_B, _ACT_SPELL5){
		let cutFrameA = 6;
		if( actionCountMax < 36 ){ cutFrameA = trunc( actionCountMax / 6 ); }
		let cutFrameB = cutFrameA * 2;
		let cutFrameC = actionCountMax - cutFrameB;
		let cutFrameD = actionCountMax - cutFrameA;
		let animePattern = [ 0, 1, 2, 1, 0 ];
		let framePattern = [ cutFrameA, cutFrameB, cutFrameC, cutFrameD, actionCountMax ];
		let anime = animePattern[ 4 ];
		ascent( let i in 0 .. 5 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		alternative( action )
		case( _ACT_SHOT_A5 ){ rect = [ RECT_SHOT_A0, RECT_SHOT_A1, RECT_SHOT_A2 ][ anime ]; }
		case( _ACT_SHOT_B5 ){ rect = [ RECT_SHOT_B0, RECT_SHOT_B1, RECT_SHOT_B2 ][ anime ]; }

		case( _ACT_SHOT_B5_B ){ rect = [ RECT_SHOT_B0, RECT_SHOT_B1, RECT_SHOT_B3 ][ anime ]; }
		others{ rect = [ RECT_SPELL0, RECT_SPELL1, RECT_SPELL2 ][ anime ]; }
	}
	//　5コマB（スペル5B, 弾幕A5C） -------------------------------------------
	case( _ACT_SPELL5_B){
		let cutFrameA = 6;
		if( actionCountMax < 36 ){ cutFrameA = trunc( actionCountMax / 6 ); }
		let cutFrameB = cutFrameA * 2;
		let cutFrameC = cutFrameA * 3;
		let cutFrameD = actionCountMax - cutFrameA;
		let animePattern = [ 0, 1, 2, 3, 2 ];
		let framePattern = [ cutFrameA, cutFrameB, cutFrameC, cutFrameD, actionCountMax ];
		let anime = animePattern[ 4 ];
		ascent( let i in 0 .. 5 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		rect = [ RECT_SPELL0, RECT_SPELL1, RECT_SPELL2, RECT_SPELL3 ][ anime ];	
	}
	//　5コマ （スペル5C） -------------------------------------------
	case( _ACT_SPELL5_C ){
		let cutFrameA = 6;
		if( actionCountMax < 36 ){ cutFrameA = trunc( actionCountMax / 6 ); }
		let cutFrameB = cutFrameA * 2;
		let cutFrameC = cutFrameA * 3;
		let cutFrameD = cutFrameA * 4;
		let cutFrameE = actionCountMax - cutFrameA;
		let animePattern = [1, 0, 1, 2, 3 ];
		let framePattern = [cutFrameA, cutFrameB, cutFrameC, cutFrameD, cutFrameE];
		let anime = animePattern[ 4 ];
		ascent( let i in 0 .. 5 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		rect = [ RECT_SPELL0, RECT_SPELL1, RECT_SPELL2, RECT_SPELL3 ][ anime ];
	}
	//　2コマ（溜め） ------------------------------------------------
	case( _ACT_CHARGE ){
		let cutFrame = 6;
		if( actionCountMax < 18 ){ cutFrame = trunc( actionCountMax / 3 ); }
		let anime = [ 0, 1 ][ actionCount >= cutFrame ];
		alternative( action )
		rect = [ RECT_SHOT_B0, RECT_SHOT_B1 ][ anime ];
	}
	//　5コマ（縦斬り,横斬り） ---------------------------------------
	case( _ACT_SLASH_H, _ACT_SLASH_V, _ACT_SLASH_H_B ){
		let cutFrameA = 6;
		if( actionCountMax < 36 ){ cutFrameA = trunc( actionCountMax / 6 ); }
		let cutFrameD = actionCountMax - cutFrameA;
		let cutFrameC = cutFrameD - cutFrameA;
		let cutFrameB = cutFrameC - cutFrameA;
		let animePattern = [ 0, 1, 2, 3, 4 ];
		let framePattern = [ cutFrameA, cutFrameB, cutFrameC, cutFrameD, actionCountMax ];
		let anime = animePattern[ 4 ];
		ascent( let i in 0 .. 5 ){
			if( actionCount < framePattern[ i ] ){
				anime = animePattern[ i ];
				break;
			}
		}
		alternative( action )
		case( _ACT_SLASH_H ){ rect = [ RECT_SHOT_B0, RECT_SHOT_B1,
			RECT_SHOT_A3, RECT_SHOT_A1, RECT_SHOT_A0 ][ anime ]; }
		case( _ACT_SLASH_V ){ rect = [ RECT_SHOT_B2, RECT_SHOT_B3,
			RECT_SHOT_A3, RECT_SHOT_A1, RECT_SHOT_A0 ][ anime ];  }
		others{ rect = [ RECT_SHOT_B0, RECT_SHOT_B1,
			RECT_SHOT_B2, RECT_SHOT_B3, RECT_SHOT_B3 ][ anime ]; }
	}
	//　6コマ（ターン） ----------------------------------------------
	case( _ACT_TURN ){
		let cutFrame = 7;
		let number = trunc( actionCount / cutFrame );
		let anime = [ 0, 1, 2, 3, 4, 0, 0 ][ number ];
		rect = [ RECT_ETC_A0, RECT_ETC_B0, RECT_ETC_B1, RECT_ETC_B2, RECT_ETC_B3 ][ anime ];
	}
	//　8コマループ（祈祷） ------------------------------------------
	case( _ACT_PRAY ){
		let cutFrame = 6;
		let anime = 0;
		if( actionCountMax < 12 ){ cutFrame = trunc( ( actionCountMax + 1 ) / 2 ); }
		if( actionCount >= cutFrame && actionCount < actionCountMax - cutFrame ){
			anime = trunc( ( actionCount - cutFrame ) / cutFrame ) % 6 + 1;
		}
		rect = [ RECT_ETC_A0, RECT_ETC_A1, RECT_ETC_A2, RECT_ETC_A3,
			RECT_ETC_B0, RECT_ETC_B1, RECT_ETC_B2, RECT_ETC_B3 ][ anime ];
	}
	//　8コマループ（衣玖専用特殊動作） ------------------------------------------
	case( _ACT_THORN ){

		let cutFrame = 6;
		let anime = 0;
		if( actionCountMax < 12 ){ cutFrame = trunc( ( actionCountMax + 1 ) / 2 ); }
		if( actionCount<=cutFrame * 3 ){
			anime = trunc( actionCount / 6 ) ;
		}
		if( actionCount >= cutFrame * 3 && actionCount < actionCountMax - cutFrame*3 ){
			anime = trunc( ( actionCount - cutFrame ) / cutFrame ) % 2 + 3;
		}
		if( actionCountMax - actionCount<=cutFrame * 3){
			let number = trunc( ( actionCountMax - actionCount )/ 6 )  ;
			let Aft_anime = [ 7, 6, 5, 5][ number ];
			anime = Aft_anime;
		}
		rect = [ RECT_ETC_A0, RECT_ETC_A1, RECT_ETC_A2, RECT_ETC_A3,
			RECT_ETC_B0, RECT_ETC_B1, RECT_ETC_B2, RECT_ETC_B3 ][ anime ];
	}
	//　4コマループ（太陽） ------------------------------------------
	case( _ACT_SUN ){
		let cutFrame = 4;
		let anime = 0;
		if( actionCountMax < 12 ){ cutFrame = trunc( ( actionCountMax + 1 ) / 2 ); }
		if( actionCount >= cutFrame && actionCount < actionCountMax - cutFrame ){
			anime = trunc( ( actionCount - cutFrame ) / cutFrame ) % 2 + 1;
		}
		rect = [ RECT_ETC_A0, RECT_ETC_A1, RECT_ETC_A2, RECT_ETC_A3][ anime ];
	}
	//　1コマ（立ち＋アニメなし） ------------------------------------
	others{ rect = RECT_STAND0; }
	//　描画 ---------------------------------------------------------
	SetTexture( imageFile );
	SetGraphicRect( rect[ 0 ], rect[ 1 ], rect[ 0 ] + RECT_LENGTH, rect[ 1 ] + RECT_LENGTH );
	DrawGraphic( x, y );

	BossShadowRect0=rect[ 0 ];
	BossShadowRect1=rect[ 1 ];
}
/////////////////////////////////////////////////////////////////
//勝手に追加分

function AnimeHueDifine(HueCount)
{
let ColorRed=0;
let ColorGreen=0;
let ColorBlue=0;
let MinColor=0;
while(HueCount>360){HueCount-=360;}
while(HueCount<=0){HueCount+=360;}
	if(0<HueCount && HueCount<=60)
	{
		ColorRed=255;
		ColorGreen=255*(HueCount)/60;
		ColorBlue=0;
	}
	else if(HueCount<=120)
	{
		ColorRed=255*(120-HueCount)/60;
		ColorGreen=255;
		ColorBlue=0;
	}
	else if(HueCount<=180)
	{
		ColorRed=0;
		ColorGreen=255;
		ColorBlue=255*(HueCount-120)/60;
	}
	else if(HueCount<=240)
	{
		ColorRed=0;
		ColorGreen=255*(240-HueCount)/60;
		ColorBlue=255;
	}
	else if(HueCount<=300)
	{
		ColorRed=255*(HueCount-240)/60;
		ColorGreen=0;
		ColorBlue=255;
	}
	else if(HueCount<=360)
	{
		ColorRed=255;
		ColorGreen=0;
		ColorBlue=255*(360-HueCount)/60;
	}
	return([ColorRed,ColorGreen,ColorBlue]);
}


let BossScaleX=1;
let BossScaleY=1;

let GlobalHueCount;

task BossShadowAnimation(imageFile,frame,R,G,B)
{
let HueCount=0;
let color=AnimeHueDifine(HueCount);
let count=0;
wait(frame);
loop
{
	if(count%2==0)
	{
	if(GetCommonDataDefault("TrueBossFlag",false)==false)
	{
	BossShadowAnimationEffect(imageFile,R,G,B);
	BossBlameAnimationEffect(imageFile,R/2,G/2,B/2);
	}
	else
	{
	color=AnimeHueDifine(HueCount);
	BossShadowAnimationEffect(imageFile,color[0],color[1],color[2]);
	BossBlameAnimationEffect(imageFile,color[0]/2,color[1]/2,color[2]/2);
	}
	}
	count+=1;
	HueCount+=3;
	GlobalHueCount=HueCount;
yield;
}
}

task BossShadowAnimationEffect(imageFile,R,G,B)
{
	let randrect=3;
	let XYrect=[];
	loop(8)
	{
	XYrect=XYrect~[RECT_LENGTH/2+rand(-randrect,randrect)];
	}
	if(GetCommonDataDefault("LightMode_BossBlur",false)){return;}
	let obj = Obj_Create(OBJ_EFFECT);

	ObjEffect_SetTexture(obj, imageFile);
	ObjEffect_SetRenderState(obj, ADD);
	ObjEffect_SetLayer(obj,1);
	ObjEffect_SetPrimitiveType(obj, PRIMITIVE_TRIANGLEFAN);
	ObjEffect_CreateVertex(obj, 4);

	ObjEffect_SetVertexXY(obj, 0, -XYrect[0], -XYrect[1]);
	ObjEffect_SetVertexXY(obj, 1, XYrect[2], -XYrect[3]);
	ObjEffect_SetVertexXY(obj, 2, XYrect[4], XYrect[5]);
	ObjEffect_SetVertexXY(obj, 3, -XYrect[6], XYrect[7]);
	ObjEffect_SetVertexUV(obj, 0, BossShadowRect0, BossShadowRect1);
	ObjEffect_SetVertexUV(obj, 1, BossShadowRect0+RECT_LENGTH, BossShadowRect1);
	ObjEffect_SetVertexUV(obj, 2, BossShadowRect0+RECT_LENGTH, BossShadowRect1+RECT_LENGTH);
	ObjEffect_SetVertexUV(obj, 3, BossShadowRect0, BossShadowRect1+RECT_LENGTH);
	Obj_SetPosition(obj, GetX, GetY);

	let Alpha=100;
	let ScaleX=BossScaleX;
	let ScaleY=BossScaleY;
/*
Obj_SetSpeed(obj,2);
Obj_SetAngle(obj,rand(0,360));
*/
	while(Alpha>0)
	{
		Obj_SetY(obj,Obj_GetY(obj)-0.15);
		ObjEffect_SetScale(obj,ScaleX,ScaleY);
		ascent(let i in 0..4)
		{
			ObjEffect_SetVertexColor(obj, i, Alpha, R, G, B);
		}
		ScaleX+=0.3/25;
		ScaleY+=0.3/25;
		Alpha-=100/25;

		yield;
	}
	Obj_Delete(obj);
}

task BossBlameAnimationEffect(imageFile,R,G,B)
{
	let randrect=5;
	let XYrect=[];
	loop(8)
	{
	XYrect=XYrect~[RECT_LENGTH/2+rand(-randrect,randrect)];
	}
	if(GetCommonDataDefault("LightMode_BossBlur",0)==1){return;}

	let obj = Obj_Create(OBJ_EFFECT);
	ObjEffect_SetTexture(obj, imageFile);
	ObjEffect_SetRenderState(obj, ADD);
	ObjEffect_SetLayer(obj,1);
	ObjEffect_SetPrimitiveType(obj, PRIMITIVE_TRIANGLEFAN);
	ObjEffect_CreateVertex(obj, 4);

	ObjEffect_SetVertexXY(obj, 0, -XYrect[0], -XYrect[1]);
	ObjEffect_SetVertexXY(obj, 1, XYrect[2], -XYrect[3]);
	ObjEffect_SetVertexXY(obj, 2, XYrect[4], XYrect[5]);
	ObjEffect_SetVertexXY(obj, 3, -XYrect[6], XYrect[7]);

	ObjEffect_SetVertexUV(obj, 0, BossShadowRect0, BossShadowRect1);
	ObjEffect_SetVertexUV(obj, 1, BossShadowRect0+RECT_LENGTH, BossShadowRect1);
	ObjEffect_SetVertexUV(obj, 2, BossShadowRect0+RECT_LENGTH, BossShadowRect1+RECT_LENGTH);
	ObjEffect_SetVertexUV(obj, 3, BossShadowRect0, BossShadowRect1+RECT_LENGTH);
	Obj_SetPosition(obj, GetX, GetY);

	let Alpha=50;
	let StandardAlpha=Alpha;
	let ScaleX=BossScaleX;
	let ScaleY=BossScaleY;
	while(Alpha>0)
	{
		Obj_SetY(obj,Obj_GetY(obj)-1);
		ObjEffect_SetScale(obj,ScaleX,ScaleY);
		ascent(let i in 0..4)
		{
			ObjEffect_SetVertexColor(obj, i, Alpha, R, G, B);
		}
		ScaleX+=0.3/10;
		ScaleY+=0.3/10;
		Alpha-=StandardAlpha/15;

		yield;
	}
	Obj_Delete(obj);
}

function waitaction(w)//10Fの時止め対応版
{
    loop(w) {
	if(GetCommonDataDefault("TimeStop",false)==true)
	{
		loop(30){yield;}
	}
	 yield; 
	}
}