#ScriptVersion[2]

script_enemy_main
{
	#include_function ".\init.txt"

	@Initialize
	{
		SetLife(60);

		SetTexture(img_fairy);

		LoadUserShotData(shot_00);

		InitializeAction();
		SetFairyType(2);

		T_Main();
		T_HitTest(16);
	}

	@Finalize
	{
		if( GetLife() <= 0 ){
			CreateItemCircle(GetX(), GetY(), 1, 0);
		}
	}

	@DrawLoop
	{
		DrawGraphic(GetX(), GetY());
	}

	task T_Main()
	{
		yield;

		T_Move();
		T_Shot();
		Wait(10);

		loop{
			if( IsOutOfClipRange(GetX(), GetY(), 16) ){
				VanishEnemy();
			}
			yield;
		}
	}

	task T_Move()
	{
		let v = GetSpeed();
		let a = -v / 30;
		loop(30){
			v += a;
			SetSpeed(v);
			yield;
		}
		Wait(120);
		if( GetX() < GetCenterX() ){
			SetAngle(-110);
		}
		else{
			SetAngle(-70);
		}
		a = 0.07;
		loop(60){
			v += a;
			SetSpeed(v);
			yield;
		}
	}

	task T_Shot()
	{
		Wait(30);
		loop(3){
			PlaySE(se_shot1);
			let angle = GetAngleToPlayer();
			ascent( let i in 0..32 ){
				CreateShotA(0, GetX(), GetY(), 0);
				SetShotDataA(0, 0, 6.0, angle, 0, -6.0 / 40, 0.0, 17);
				SetShotDataA(0, 40, rand(0.8, 2.0), rand(0, 360), 0, 0, 0, 17);
				FireShot(0);
				angle += 360 / 32;
			}
			Wait(15);
		}
	}

	#include_function ".\f_base.txt"
	#include_function ".\f_enemy.txt"
	#include_function ".\f_anime_fairy.txt"
}
