東方弾幕風[Single]
#ScriptVersion[2]
#Title[白百合スペル2]

script_enemy_main{
	
	@Initialize{
		//データ初期化
		InitializeData();
		InitializeAction();
		
		//スペカインデックス決定
		spellNumber = "3";
		
		//スペカ分母を1増やして取得
		SetSpellData( player, difficult, spellNumber, "Parent" );
		spellPC = GetSpellData( player, difficult, spellNumber );
		
		//スペカ背景コントロールタスク起動
		BackGroundControl();
		
		//ライフ設定
		SetLife( 1000 );
		//初期位置設定
		Warp( CenterX, MinY + 100, 40 );
		//ダメージレート設定
		SetDamageRate( 25, 25 );
		//当たり判定設定
		SetCollisionEx( 32, 16, false, 180 );
		//エネミーマーカー
		SetEnemyMarker( true );
		
		//メインタスク開始
		TMain();
	}
	
	@MainLoop{
		//yieldループ
		yield;
	}
	
	@DrawLoop{
		//ボス画像描画
		SetGraphicScale( xscale, yscale );
		DrawBoss( imgBoss );
		
		//暫定スペカ履歴描画
		DrawText( IntToString( spellPC[ 0 ] ), 340, 64, 12, 255 );
		DrawText( "/",                         360, 64, 12, 255 );
		DrawText( IntToString( spellPC[ 1 ] ), 380, 64, 12, 255 );
	}
	
	@BackGround{
		//背景描画設定時のみ背景描画
		if( isDrawBackGround ){
			BackGroundDraw();
		}
	}
	
	@Finalize{
		//最終処理
		FinalizeData();
		
		//スペカを取得していた場合取得数プラス
		if( GotSpellCardBonus() ){
			SetSpellData( player, difficult, spellNumber, "Child" );
		}
	}
	
	/**
	 * メインタスク
	 */
	task TMain(){
		//60F(1秒)待つ
		FWait( 60 );
		
		//スペカ宣言
		DeclareSpell();
		
		//弾幕アクション
		SetAction( ACT_SHOT_B, 21600 );
		
		//攻撃分岐
		alternative( difficult )
			case( "Easy" ){
				Atack_Easy();
			}
			case( "Normal" ){
				Atack_Normal();
			}
			case( "Panic" ){
				Atack_Panic();
			}
	}
	
	/**
	 * スペカ宣言
	 */
	function DeclareSpell(){
		//スペカ名取得
		let spellname = GetSpellName( player, difficult, spellNumber );
		
		//スコア設定
		SetScore( 20000000 );
		//制限時間設定
		SetTimer( 51 );
		//カットイン
		CutIn( KOUMA, spellname, NULL, 0, 0, 0, 0 );
		//スペカ発動音
		PlaySE( seUseSpell );
		//スペル発動アクション
		SetAction( ACT_SPELL, 120 );
		//120F(2秒)待つ
		FWait( 120 );
	}
	
	/**
	 * Easy 攻撃メインタスク
	 */
	task Atack_Easy(){
	}
	
	/**
	 * Normal 攻撃メインタスク
	 */
	task Atack_Normal(){
	}
	
	/**
	 * Panic 攻撃メインタスク
	 */
	task Atack_Panic(){
		let angle = 0;
		let way = 10;
		let waitspan = 40;
		let speed = 3.2;
		let accspeed = 0.0055;
		let rollangle = 2.2;
		let turn = 1;
		
		loop{
			angle = rand( 0, 360 );
			ascent( i in 0..way ){
				CreateCherryShot( GetX() + 92, GetY(), speed, angle + i * 360 / way, PURPLE23, 20, 1, rollangle, accspeed,  1 );
				CreateCherryShot( GetX() - 92, GetY(), speed, angle + i * 360 / way, PURPLE23, 20, 1, rollangle, accspeed, -1 );
			}
			
			FWait( waitspan );
		}
	}
	
	/**
	 * 分裂チェリー弾
	 */
	task CreateCherryShot( x, y, speed, angle, graph, delay, slife, ang, vspeed, turn ){
		let sangle = angle;
		
		let obj = CreateObjShot( x, y, speed, angle, graph, delay );
		Obj_SetAutoDelete( obj, false );
		
		while( !Obj_BeDeleted( obj ) ){
			Obj_SetSpeed( obj, speed );
			Obj_SetAngle( obj, sangle );
			
			sangle += ang * turn;
			speed += vspeed;
			
			if( absolute( sangle - angle ) >= 180 ){
				if( slife == 1 ){
					ascent( i in 0..3 ){
						CreateCherryShot( Obj_GetX( obj ), Obj_GetY( obj ), speed, Obj_GetAngle( obj ) + ( 1.4 * ( i - 1 ) * turn ), graph, 0, 0, ang, vspeed, turn );
					}
				}else{
					ascent( i in 0..5 ){
						CreateShot01( Obj_GetX(obj), Obj_GetY(obj), speed * ( 15 - i ) / 15, Obj_GetAngle( obj ) + 14 * ( ( i - 2 ) * turn ), graph, 0 );
					}
				}
				
				if( !Obj_BeDeleted( obj ) ){
					Obj_Delete( obj );
				}
			}
			
			yield;
		}
	}
	
	//スクリプトのインクルード
	#include_function ".\initialize.txt"
}