東方弾幕風[Single]
#ScriptVersion[2]
#Title[白百合スペル3]

script_enemy_main{
	
	@Initialize{
		//データ初期化
		InitializeData();
		InitializeAction();
		
		//スペカインデックス決定
		spellNumber = "4";
		
		//スペカ分母を1増やして取得
		SetSpellData( player, difficult, spellNumber, "Parent" );
		spellPC = GetSpellData( player, difficult, spellNumber );
		
		//スペカ背景コントロールタスク起動
		BackGroundControl();
		
		//ライフ設定
		SetLife( 1000 );
		//初期位置設定
		Warp( CenterX, MinY + 100, 40 );
		//ダメージレート設定
		SetDamageRate( 25, 25 );
		//当たり判定設定
		SetCollisionEx( 32, 16, false, 180 );
		//エネミーマーカー
		SetEnemyMarker( true );
		
		//メインタスク開始
		TMain();
	}
	
	@MainLoop{
		//yieldループ
		yield;
	}
	
	@DrawLoop{
		//ボス画像描画
		SetGraphicScale( xscale, yscale );
		DrawBoss( imgBoss );
		
		//暫定スペカ履歴描画
		DrawText( IntToString( spellPC[ 0 ] ), 340, 64, 12, 255 );
		DrawText( "/",                         360, 64, 12, 255 );
		DrawText( IntToString( spellPC[ 1 ] ), 380, 64, 12, 255 );
	}
	
	@BackGround{
		//背景描画設定時のみ背景描画
		if( isDrawBackGround ){
			BackGroundDraw();
		}
	}
	
	@Finalize{
		//最終処理
		FinalizeData();
		
		//スペカを取得していた場合取得数プラス
		if( GotSpellCardBonus() ){
			SetSpellData( player, difficult, spellNumber, "Child" );
		}
	}
	
	/**
	 * メインタスク
	 */
	task TMain(){
		//60F(1秒)待つ
		FWait( 60 );
		
		//スペカ宣言
		DeclareSpell();
		
		//スペル発動アクション
		SetAction( ACT_SHOT_B, 21600 );
		
		//攻撃分岐
		alternative( difficult )
			case( "Easy" ){
				Atack_Easy();
			}
			case( "Normal" ){
				Atack_Normal();
			}
			case( "Panic" ){
				Atack_Panic();
			}
	}
	
	/**
	 * スペカ宣言
	 */
	function DeclareSpell(){
		//スペカ名取得
		let spellname = GetSpellName( player, difficult, spellNumber );
		
		//スコア設定
		SetScore( 20000000 );
		//制限時間設定
		SetTimer( 45 );
		//カットイン
		CutIn( KOUMA, spellname, NULL, 0, 0, 0, 0 );
		//スペカ発動音
		PlaySE( seUseSpell );
		//スペル発動アクション
		SetAction( ACT_SPELL, 120 );
		//120F(2秒)待つ
		FWait( 120 );
	}
	
	/**
	 * Easy 攻撃メインタスク
	 */
	task Atack_Easy(){
	}
	
	/**
	 * Normal 攻撃メインタスク
	 */
	task Atack_Normal(){
	}
	
	/**
	 * Panic 攻撃メインタスク
	 */
	task Atack_Panic(){
		let angle1 = 90;
		let angle2 = 90;
		let roll = 2.2;
		let sangle1 = 90;
		let sangle2 = 90;
		let sroll = 11.7;
		let graph = 0;
		if( isDrawEffect ){
			graph = US_BALL_S_A_WHITE;
		}else{
			graph = US_BALL_S_WHITE;
		}
		
		loop{
			angle1 += roll;
			angle2 -= roll;
			sangle1 += sroll;
			sangle2 -= sroll;
			ascent(i in 0..2){
				WhiteShot( GetX(), GetY(), 1.24 + i * 0.3, angle1, graph, 0, sangle1 );
				WhiteShot( GetX(), GetY(), 1.24 + i * 0.3, angle2, graph, 0, sangle2 );
			}
			yield;
		}
	}
	
	task WhiteShot( x, y, speed, angle, graph, delay, sangle ){
		let obj = CreateObjShot( x, y, speed, angle, graph, delay );
		let scount = 80;
		FWait( delay + scount );
		if( !Obj_BeDeleted( obj ) ){
			let x = Obj_GetX( obj );
			let y = Obj_GetY( obj );
			CreateShot02( x, y, 2.2, sangle      , 0.03, 3.8, PURPLE23, 24 );
			CreateShot02( x, y, 2.2, sangle + 180, 0.03, 3.8, PURPLE23, 24 );
			if( isDrawEffect ){
				ObjShot_FadeDelete( obj );
			}else{
				Obj_Delete( obj );
			}
		}
	}
	
	//スクリプトのインクルード
	#include_function ".\initialize.txt"
	#include_function ".\..\..\..\Library\lib_effect.txt"
}