// ファイルのインクルード
#include_function ".\..\..\initialize_boss.txt"

#include_function ".\..\..\..\Library\lib_anime.txt"
#include_function ".\..\..\..\Library\lib_anime_lily.txt"

//ワープ用
let xscale = 1;
let yscale = 1;

/**
 * 共通で最初に実行される部分
 */
function InitializeData(){
	//魔法陣の色
	magicColor = MAGIC_PURPLE;
	
	//ボス共通初期化処理
	InitializeBossData();
	
	//画像設定
	imgBoss = imgBoss_LilyWhite;
}

/**
 * 共通で最後に実行される部分
 */
function FinalizeData(){
	//ボス共通最終処理
	FinalizeBossData();
	
	//ワープ対策
	SetGraphicScale( 1, 1 );
}

/**
 * リリー風ワープ移動
 * 
 * @param {Integer} x    移動先x座標
 * @param {Integer} y    移動先y座標
 * @param {Integer} time 移動時間
 */
task Warp( x, y, time ){
	let warptime = 8;
	
	loop( warptime ){
		xscale -= 1 / warptime;
		yscale += 0.5 / warptime;
		
		yield;
	}
	
	SetX( x );
	SetY( y );
	
	FWait( time - warptime * 2 );
	
	loop( warptime ){
		xscale += 1 / warptime;
		yscale -= 0.5 / warptime;
		
		yield;
	}
	
	xscale = 1;
	yscale = 1;
}

/**
 * スペル背景描画
 */
function BackGroundDraw(){
	SetTexture( imgBack_Stage1_Spell_1 );
	SetGraphicRect( 0, 0, 512, 512 );
	SetGraphicScale( 1.5, 1.5 );
	SetAlpha( 32 );
	DrawGraphic( CenterX, CenterY );
	SetAlpha( 255 );
	SetGraphicScale( 1, 1 );
}

/**
 * スペル背景コントロールタスク
 */
task BackGroundControl(){
}
