script_event Start0{
	@Initialize{}

	@MainLoop{
		Wait(10);
		if(GetPlayerType==REIMU_A || GetPlayerType==REIMU_B){
			TextOutB(100,"\c[RED]む、こんなところで会うとは……");
			TextOutB(100,"\c[BLUE]天人のお守はどうしたのよ？");
			TextOutB(100,"\c[RED]いえ、今日はとある妖精に用があって来ました");
			TextOutB(100,"\c[RED]そして、此処であったのも何かの縁……\n少しだけ遊んでいきましょうか");
			}
		else if(GetPlayerType==MARISA_A || GetPlayerType==MARISA_B){
			TextOutB(100,"\c[RED]む、こんなところで会うとは……");
			TextOutB(120,"\c[BLUE]お？\nまた近々地震でも起きるのか？");
			TextOutB(100,"\c[RED]いえ、今日はとある妖精に用があって来ました");
			TextOutB(100,"\c[RED]そして、此処であったのも何かの縁……\n少しだけ遊んでいきましょうか");
			} else {
			TextOutB(100,"\c[RED]なにやら騒がしいみたいですね");
			TextOutB(100,"\c[RED]妖精たちの穏便な生活を守る為にも、\n人肌脱ぐとしましょうか");
			}
		Wait(50);
		End;
	}
	@Finalize{}
}

script_enemy_main
{
        let count=0;
        let csd     = GetCurrentScriptDirectory;
        let imgBoss =csd~"img\dot_iku.png";
	let Motion=0;
	let angle=0;
        let cx=GetCenterX();
        let cy=GetCenterY();
	let AnimationA=0;
	let AnimationB=0;

    @Initialize {
        SetLife(50);
        SetScore(0);
        SetDamageRate(0,0);
        SetX(-10);
        SetY(-10);
        SetMovePosition02(GetCenterX(),150,60);
	LoadGraphic(imgBoss);
        TAnime1;
	TAnime2;
	TEvent;
    }

    @MainLoop {
        SetCollisionA(GetX(),GetY(),18);
        SetCollisionB(GetX(),GetY(),18);
        yield;
    }

        @DrawLoop {
		SetRenderState(ALPHA);
		SetTexture(imgBoss);
		SetGraphicScale(1,1);
		SetAlpha(255);
		SetColor(255,255,255);
		SetGraphicAngle(0,0,0);
		if(int(GetSpeedX())==0)
		{SetGraphicRect(0,128*AnimationB,127,127+128*AnimationB);}
		else if(GetSpeedX()>0){SetGraphicRect(256,256+128*AnimationA,383,383+128*AnimationA);}
		else if(GetSpeedX()<0){SetGraphicRect(256,128*AnimationA,383,127+128*AnimationA);}
		DrawGraphic(GetX(),GetY());
	}

        @Finalize
        {
        } 
    	task TAnime1{
		loop{
			AnimationB=0;
        		loop(10){yield;}
			AnimationB=1;
        		loop(10){yield;}
			AnimationB=2;
        		loop(10){yield;}
			}
		}

    	task TAnime2{
			AnimationA=0;
        		loop(10){yield;}
			AnimationA=1;
        		loop(40){yield;}
			AnimationA=0;
        		loop(10){yield;}
		}
	task TEvent{
		CreateEventFromScript("Start0");
		while(OnEvent){yield;}
		AddLife(-1000);
		}
}