#e
#Title[s|uGAV[^[v]
#ScriptVersion[2]
#Player[FREE]
#Text[]
#BackGround[User]

script_enemy_main
{
let GC=GetCurrentScriptDirectory;
@Initialize
{
LoadGraphic(GC~".\main2.png");
SetTexture(GC~".\main2.png");
SetGraphicRect(0,0,32,32);
SetLife(4000);
SetTimer(80);
CutIn(KOUMA,"s|uGAV[^[v","",0,0,0,0);
SetScore(100000);
Tmain;
//CreateDebugWindow;
}
@MainLoop
{
SetCollisionA(GetX,GetY,24);
SetCollisionB(GetX,GetY,12);
OutputDebugString(0,"enemy",GetEnemyNum);
yield;
}
@DrawLoop
{DrawGraphic(GetX,GetY);}
@Finalize
{
AddScore(10000);
loop(30){CreateItem(ITEM_SCORE,GetX+rand(-40,40),GetY+rand(-30,30));}
}

task Tmain
{
loop(80){yield};
pattern(5);
CollectItems;
SetMovePosition03(GetCenterX,GetClipMinY+80,15,8);
loop(60){yield};
pattern(0);
let left=1;
loop
	{
	loop(3)
		{
		let way=trunc(rand(25,30));
		let xpitch=(GetClipMaxX-GetClipMinX)/(way);
		let xcount=0;
		let ypitch=(GetClipMaxY-50-(GetClipMinY+120))/(way-1);
		let ycount=trunc(rand(0,way-1));
	loop(2)
	{
		loop(way)
			{
			xcount=xcount+1;
			ycount=trunc(rand(1,way-1));
			CreateEnemyFromScript("shoot",GetX,GetY,0,xcount*xpitch,ycount*ypitch);
			}
	xcount=0;
	}
		xcount=GetX/xpitch-8;
		loop(6)
			{
			xcount=xcount+2;
			ycount=way-2+trunc(rand(0,5));
			CreateEnemyFromScript("shoot",GetX,GetY,0,xcount*xpitch,ycount*ypitch);
			}

		Tair;
		loop(210){yield};	
		}
	SetGraphicAngle(90-90*left,0,0);
	pattern(5);
	SetMovePosition03(GetX+(GetCenterX+120*left-GetX)*1/3,GetY,15,8);
	loop(40){yield};
	SetMovePosition03(GetCenterX+120*left,GetY,15,8);
	loop(80){yield};
	pattern(0);
	SetGraphicAngle(90+90*left,0,0);
	left=left*-1;
	}
}

task Tair
{
let press=0;
let psp=GetPlayerInfo(PLAYER_SPEED_HIGH);
let dpress=psp/40;
loop(100){yield;}
loop(130)
	{
	if(press<psp+2){press=press+dpress;}	
	SetPlayerY(GetPlayerY+press);
	yield;	
	}
}

function pattern(let rec)
{
let round=4;
SetGraphicRect(32*rec,32*round,32+32*rec,32+32*round);
}

}

script_enemy shoot
{
@Initialize
{
LoadGraphic(GetCurrentScriptDirectory~".\shot.png");
SetTexture(GetCurrentScriptDirectory~".\shot.png");
SetGraphicRect(0,0,16,16);
SetLife(100);
SetDamageRate(0,100);
SetAlpha(200);
Tmain;
}
@MainLoop
{
SetCollisionA(GetX,GetY,12);
SetCollisionB(GetX,GetY,4);
yield;
}
@DrawLoop
{
DrawGraphic(GetX,GetY);
}
@Finalize
{
}
task Tmain
{
Tanime;
let TX=GetClipMinX+GetAngle;
let TY=GetClipMinY+120+GetArgument;
SetMovePosition03(TX,TY,1,8);
loop(110){yield;}
SetAngle(90);
while(GetY<GetClipMaxY+50)
	{
	if(GetSpeed<6){SetSpeed(GetSpeed+0.05);}
	yield;
	}
VanishEnemy;
}

task Tanime
{
let pat=0;
loop
	{
	pat=(pat+1)%2;
	SetGraphicRect(0,16*pat,16,16*pat+16);
	loop(4){yield;}
	}
}

}