script_enemy_main
//fairyB8aroundL
{
let GC=GetCurrentScriptDirectory;
let left=1;
@Initialize
{
LoadGraphic(GC~".\fairy.png");
SetTexture(GC~".\fairy.png");
SetLife(20);
Tmain;
Tanime;
}
@MainLoop
{SetCollisionA(GetX,GetY,20);SetCollisionB(GetX,GetY,10);yield;}
@DrawLoop
{DrawGraphic(GetX,GetY);}
@Finalize
{
AddScore(1000);
if(GetArgument==0)
	{
	let pow=GetCommonDataDefault("pow",0);
	SetCommonData("pow",pow+1);
	SetCommonData(ToString(pow),GetX);
	SetCommonData(ToString(pow+2000),GetY);
	}
else
	{
	CreateItem(ITEM_SCORE,GetX,GetY);
	}
}

task Tmain
{
loop(30){yield};
loop(50){SetSpeed(GetSpeed-0.05);yield;}
loop(50){yield};
Tattack;
loop(120){yield};
SetAngle(90-60*left);
loop(28){SetSpeed(GetSpeed+0.1);yield;}
loop(300){yield};
VanishEnemy;
}

task Tanime
{
let pat=GetArgument;
loop
	{
	SetGraphicRect(24*pat,0,24*pat+24,24);loop(10){yield};
	SetGraphicRect(24*pat,24,24*pat+24,48);loop(10){yield};
	}
}

task Tattack
{
let angle=0;
loop(8)
	{
	CreateShot02(GetX,GetY,4,angle,-1/20,2,RED04,10);
	angle=angle+45;
	}
}

}