script_enemy_main
{
        let csd     = GetCurrentScriptDirectory;
	let speed = GetSpeed;
	let angle = GetAngle;
	let num = GetArgument;
	let imgEnemy=csd~"..\lib\fairy_green.png";
	let SelectedDifficult=GetCommonDataDefault("SELECTEDDIFFICULT","Normal");
    @Initialize {
        SetLife(60);
	SetTexture(imgEnemy);
        SetDamageRate(100,100);
	Initialize_Fairy(4);
	Tmain;
	}

    @MainLoop {
	SetCollisionA(GetX(),GetY(),32);
        SetCollisionB(GetX(),GetY(),16);
	yield;
    }

        @DrawLoop {
		DrawFairy(imgEnemy );
	}

        @Finalize
        {
		if(!BeVanished)
		{
			ItemSet(GetX+rand(-20,20),GetY+rand(-20,20),1);
			ItemSet(GetX+rand(-20,20),GetY+rand(-20,20),1);
			ItemSet(GetX+rand(-20,20),GetY+rand(-20,20),2);
			ItemSet(GetX+rand(-20,20),GetY+rand(-20,20),2);
		}
        } 

task Tmain
{
yield;
GetDamege;
move;
shot;
eraze;
}

task GetDamege
{
loop
{
	if(GetHitCount!=0)
	{
		SetColor(150,150,255);
		wait(10);
	}
	else
	{
		SetColor(255,255,255);
	}
yield;
}
}

task move
{
	SetAngle(angle);

loop(125)
{
	SetSpeed(speed);
	SetAngle(angle);
	yield;
	speed-=0.04;
}
	SetAngle(180-angle);
loop(80)
{
	SetSpeed(speed);
	yield;
	speed+=0.04;
}
loop(80)
{
	SetSpeed(speed);
	yield;
	speed-=0.04;
}
	SetAngle(angle);
loop
{
	SetSpeed(speed);
	yield;
	speed+=0.04;
}
}

task shot
{
wait(20);
alternative(SelectedDifficult)
case("Easy")
{
	loop
	{
		CreateShot01(GetX+10,GetY,2,90,RED12,0);
		CreateShot01(GetX-10,GetY,2,90,RED12,0);
		wait(30);
	}
}
case("Normal")
{
	loop
	{
		CreateShot01(GetX+10,GetY,2.5,90,RED12,0);
		CreateShot01(GetX-10,GetY,2.5,90,RED12,0);
		wait(20);
	}
}
case("Hard")
{
	loop
	{
		loop(2)
		{
		CreateShot01(GetX+10,GetY,3,90,RED12,0);
		CreateShot01(GetX-10,GetY,3,90,RED12,0);
		wait(5);
		}
		wait(20);
	}
}
case("Lunatic")
{
	loop
	{
		loop(3)
		{
		CreateShot01(GetX+10,GetY,3.5,90,RED12,0);
		CreateShot01(GetX-10,GetY,3.5,90,RED12,0);
		wait(5);
		}
		wait(20);
	}
}
}

task eraze
{
while(!BeVanished)
{
        	if(GetX<GetClipMinX-64||GetX>GetClipMaxX+64||GetY<GetClipMinY-32||GetY>GetClipMaxY+32)
        	{
        		VanishEnemy();
        	}
yield;
}
}


#include_function ".\..\txt/StageEnemydata.txt"
#include_function ".\..\lib\lib_anime_fairy.txt"
}

