script_enemy_main {
    let time = 0;
    let phase = 1;
    let rate = 0;
    let life = 0;
    let kaku = 10;
    let score = 120;
    let lv = 0;
    let angle = GetAngle();
    let rank = GetSpeed();
    let arg = GetArgument();
    let ex = GetCommonData("ex");
    let mapx = GetX();
    let mapy = GetY();
    let imgEnemy = GetCurrentScriptDirectory~"img\zakohune1.png";
    let tama = GetCurrentScriptDirectory~"tama.txt";
    let se1 = GetCurrentScriptDirectory~"wav\se1.wav";
    let se3 = GetCurrentScriptDirectory~"wav\se3.wav";
    @Initialize(){
        SetLife( 130 );
        SetInvincibility( 10 );
        LoadGraphic( imgEnemy );
        LoadUserShotData( tama );
        SetX(mapx-GetCommonData("bgx"));
        SetY(GetCommonData("bgy")-mapy);
        if(arg==0){
           if( (|angle|) ==102){Tmove102;}
           if( (|angle|) ==103){Tmove103;}
           if( (|angle|) ==105){Tmove105;}
        }
        else{setmove(angle,arg);}
        Tshot;
    }
    @MainLoop {
        rate=life-GetLife;
        life=GetLife;
        if(phase==1&&GetLife<=100){
           phase-=1;
           if(lv==0||GetPoint>0){DeleteEnemyShotImmediatelyInCircle(SHOT, GetX, GetY, 30);}
           PlaySE(se3);
           Tdeath(4,24,2,1);
           CreateEnemyFromFile(GetCurrentScriptDirectory~"landitem.txt",mapx,mapy, 0, 0, 2);
        }
        if(GetX<12||GetX>436||GetY<16){
           SetInvincibility( 5 );
        }
        if(time>240&&GetY>500){VanishEnemy;}
        if(time>1500){VanishEnemy;}
        if(phase>=1){SetCollisionA(GetX, GetY, 24);}
        SetX(mapx-GetCommonData("bgx"));
        SetY(GetCommonData("bgy")-mapy);
        lv=GetCommonData("rank");
        time++;
        yield;
    }
    @Finalize() {
    }
    @DrawLoop {
	SetTexture( imgEnemy );
        SetGraphicRect( 1, 1, 48, 48 );
        SetGraphicAngle(0,0,angle);
	DrawGraphic( GetX()+cos(angle)*8, GetY()+sin(angle)*8 );
        SetGraphicRect( 48, 1, 96, 48 );
        SetGraphicAngle(0,0,GetAngleToPlayer()-GetAngleToPlayer()%12+6);
	DrawGraphic( GetX(), GetY() );
    }

    task Tshot{
        yield;
        wait(60+sin(GetCommonData("ransu")*73)*20);
        SetCommonData("ransu",GetCommonData("ransu")+1);
        loop{
           if(GetX>32&&GetX<416&&GetY>16&&GetY<(300+rank*20)&&(GetX-GetPlayerX)^2+(GetY-GetPlayerY)^2>150^2){
              let p=GetAngleToPlayer();
              p+=-p%12+6;
              SetShotDirectionType(ABSOLUTE);
              let a=0;
              loop(3){
                 CreateShotFromScript( "shot1",GetX()+cos(p)*20, GetY()+sin(p)*20, 2.2+ex*0.5, p+a*7, 0, 06);
                 if(ex==1){CreateShotFromScript( "shot1",GetX()+cos(p)*20, GetY()+sin(p)*20, 3.4, p+a*7, 0, 06);}
                 a++;
              }
           }
           wait(92-lv*16);
        }
    }
    task Tmove102{
        angle=-32;
        setmove(-32,250);
        wait(250);
        angle=0;
        setmove(0,600);
        wait(600);
        VanishEnemy;
    }
    task Tmove103{
        angle=180;
        setmove(180,420);
        wait(420);
        angle=148;
        setmove(148,300);
        wait(300);
        VanishEnemy;
    }

    task Tmove105{
        angle=32;
        setmove(32,200);
        wait(200);
        angle=53;
        setmove(53,270);
        wait(270);
        angle=32;
        setmove(32,300);
        wait(300);
        VanishEnemy;
    }

   task setmove(a,t) {
      loop(t) {
         mapx+=cos(a)*0.8;mapy-=sin(a)*0.8;
         yield;
      }
   }



    #include_function".\efanction.txt"
}

#include_script".\escript.txt"